chflags nohidden ~/Library

Reeder

Pages

Numbers

Keynote

Xcode

Aperture

Motion

Wunderlist

Hype

桜花

Sparrow Lite

MiroVideoConverter (MVC)

Evernote

Minutes

TextWrangler

Twitter

Coda

javac -version

-javaagent:/Applications/eclipse/plugins/jp.sourceforge.mergedoc.pleiades/pleiades.jar

/Applications/eclipse/ecipse -clean

https://dl-ssl.google.com/android/eclipse/

StackNumber.as
package jp.feb19.gof.interpreter
{
	public class StackNumber
	{
		private var _stack:Array;
		private var _sp:int;
		
		public function StackNumber()
		{
			_sp = -1;
			_stack = [];
		}
		
		public function push(num:Number):void
		{
			_stack[++_sp] = num;
		}
		
		public function pop():Number
		{
			return (isEmpty()) ? 0 : _stack[_sp--];
		}
		
		public function isEmpty():Boolean
		{
			return _sp <= -1;
		}
	}
}

StackString.as
package jp.feb19.gof.interpreter
{
	public class StackString
	{
		private var _stack:Array;
		private var _sp:int;
		
		public function StackString()
		{
			_sp = -1;
			_stack = [];
		}
		
		public function push(str:String):void
		{
			_stack[++_sp] = str;
		}
		
		public function pop():String
		{
			return (isEmpty()) ? "" : _stack[_sp--];
		}
		
		public function isEmpty():Boolean
		{
			return _sp <= -1;
		}
	}
}

InterpreterTest.as
package jp.feb19.gof.interpreter
{
	import flash.display.Sprite;
	
	public class InterpreterTest extends Sprite
	{
		public function InterpreterTest()
		{
			super();
			
			var input:String = "1+2*3";
			trace(input);
			var interpreter:Interpreter = new Interpreter();
			var postfix:String = interpreter.convertToPostfix(input);
			trace(postfix);
			var result:Number = interpreter.evaluate(postfix);
			trace(result);
		}
	}
}

1+2*3
123*+
7

Calculator.as
package jp.feb19.gof.command
{
	public class Calculator	//Receiver
	{
		private var _curr:int = 0;
		
		public function Calculator()
		{
			
		}
		
		public function operation(operator:String, operand:int):void
		{
			switch(operator)
			{
				case "+":	_curr += operand;	break;
				case "-":	_curr -= operand;	break;
				case "*":	_curr *= operand;	break;
				case "/":	_curr /= operand;	break;
			}
			
			trace("current value=" + _curr + " (" + operator + " " + operand + ")");
		}
	}
}

Invoker.as
package jp.feb19.gof.command
{
	public class Invoker
	{
		private var _calculator:Calculator;
		private var _commands:Array;
		private var _current:int;
		
		public function Invoker()
		{
			_calculator = new Calculator();
			_commands = [];
			_current = 0;
		}
		
		public function redo(levels:int):void
		{
			trace(levels + "回リドゥ");
			for (var i:int = 0; i < levels; i++)
			{
				if (_current < _commands.length - 1)
				{
					var command:Command = _commands[_current++];
					command.execute();
				}
			}
		}
		
		public function undo(levels:int):void
		{
			trace(levels + "回アンドゥ");
			for (var i:int = 0; i < levels; i++)
			{
				if (_current > 0)
				{
					var command:Command = _commands[--_current] as Command;
					command.unexecute();
				}
			}
		}
		
		public function compute(operator:String, operand:int):void
		{
			var command:Command = new CalculatorCommand(_calculator, operator, operand);
			command.execute();
			
			_commands.push(command);
			_current++;
		}
	}
}

CalculatorCommand.as
package jp.feb19.gof.command
{
	public class CalculatorCommand extends Command	// ConcreteCommand
	{
		private var _calculator:Calculator;
		private var _operator:String;
		private var _operand:int;
		
		public function CalculatorCommand(calculator:Calculator, operator:String, operand:int)
		{
			_calculator = calculator;
			_operator = operator;
			_operand = operand;
			
			super();
		}
		
		public function set operator(value:String):void
		{
			_operator = value;
		}
		
		public function set operand(value:int):void
		{
			_operand = value;
		}
		
		override public function execute():void
		{
			_calculator.operation(_operator, _operand);
		}
		
		override public function unexecute():void
		{
			_calculator.operation(undo(_operator), _operand);
		}
		
		private function undo(value:String):String
		{
			switch(value)
			{
				case "+":	return "-";
				case "-":	return "+";
				case "*":	return "/";
				case "/":	return "*";
				default:	throw new ArgumentError("演算子エラー: " + value);
			}
		}
	}
}

CommandTest.as
package jp.feb19.gof.command
{
	import flash.display.Sprite;
	
	public class CommandTest extends Sprite
	{
		public function CommandTest()
		{
			super();
			
			var invoker:Invoker = new Invoker();
			
			invoker.compute("+", 100);
			invoker.compute("-", 30);
			invoker.compute("*", 50);
			invoker.compute("/", 4);
			
			invoker.undo(4);
			
			invoker.redo(3);
		}
	}
}

current value=100 (+ 100)
current value=70 (- 30)
current value=3500 (* 50)
current value=875 (/ 4)
4回アンドゥ
current value=3500 (* 4)
current value=70 (/ 50)
current value=100 (+ 30)
current value=0 (- 100)
3回リドゥ
current value=100 (+ 100)
current value=70 (- 30)
current value=3500 (* 50)

ProxyLogin.as
package jp.feb19.gof.proxy
{
	public class ProxyLogin implements ISecurity
	{
		private var _username:String;
		private var _loggedIn:ISecurity;
		
		public function ProxyLogin(username:String)
		{
			_username = username;
		}
		
		public function login():void
		{
			if (_loggedIn == null)
			{
				_loggedIn = new RealLogin(_username);
			}
			_loggedIn.login();
		}
	}
}

RealLogin.as
package jp.feb19.gof.proxy
{
	public class RealLogin implements ISecurity
	{
		private var _username:String;
		
		public function RealLogin(username:String)
		{
			_username = username;
			
			trace(_username + " をログインします");
		}
		
		public function login():void
		{
			trace("ログイン済み: " + _username);
		}
	}
}

ProxyTest.as
package jp.feb19.gof.proxy
{
	import flash.display.Sprite;
	
	public class ProxyTest extends Sprite
	{
		public function ProxyTest()
		{
			super();
			
			var user1:ISecurity = new ProxyLogin("user1");
			var user2:ISecurity = new ProxyLogin("user2");
			var user3:ISecurity = new ProxyLogin("user3");
			
			user1.login();
			user2.login();
			user2.login();
			user3.login();
			user2.login();
			
		}
	}
}

user1 をログインします
ログイン済み: user1
user2 をログインします
ログイン済み: user2
ログイン済み: user2
user3 をログインします
ログイン済み: user3
ログイン済み: user2